创建一台ECS实例

操作步骤

1. 创建专有网络和交换机。

   1. 创建terraform.tf文件，输入以下内容，并保存在当前的执行目录中。

      variable "region" {
        default = "cn-beijing"
      }
      
      variable "instance_type" {
        default = "ecs.n4.large"
      }
      
      provider "alicloud" {
        region = var.region
      }
      
      data "alicloud_zones" "default" {
        available_disk_category     = "cloud_efficiency"
        available_resource_creation = "VSwitch"
        available_instance_type     = var.instance_type
      }
      
      resource "alicloud_vpc" "vpc" {
        vpc_name   = "tf_test_foo"
        cidr_block = "172.16.0.0/12"
      }
      
      resource "alicloud_vswitch" "vsw" {
        vpc_id     = alicloud_vpc.vpc.id
        cidr_block = "172.16.0.0/21"
        zone_id    = data.alicloud_zones.default.zones.0.id
      }

   2. 运行terraform init进行初始化。

   3. 运行terraform apply开始创建。

   4. 运行terraform show查看已创建的专有网络和交换机。

      您也可以登录VPC控制台查看专有网络和交换机的属性。

2. 在上一步创建的专有网络中创建一个安全组，并添加一个允许任何地址访问的安全组规则。

   1. 在terraform.tf文件中增加以下内容。

      resource "alicloud_security_group" "default" {
        security_group_name = "default"
        vpc_id              = alicloud_vpc.vpc.id
      }
      
      resource "alicloud_security_group_rule" "allow_all_tcp" {
        type              = "ingress"
        ip_protocol       = "tcp"
        nic_type          = "intranet"
        policy            = "accept"
        port_range        = "1/65535"
        priority          = 1
        security_group_id = alicloud_security_group.default.id
        cidr_ip           = "0.0.0.0/0"
      }

   2. 运行terraform apply开始创建。

   3. 运行terraform show查看已创建的安全组和安全组规则。

      您也可以登录ECS控制台查看安全组和安全组规则。

3. 创建ECS实例。

   1. 在terraform.tf文件中增加以下内容。

      resource "alicloud_instance" "instance" {
        # cn-beijing
        availability_zone = data.alicloud_zones.default.zones.0.id
        security_groups   = alicloud_security_group.default.*.id
        # series III
        instance_type              = var.instance_type
        system_disk_category       = "cloud_efficiency"
        image_id                   = var.image_id
        instance_name              = "test_foo"
        vswitch_id                 = alicloud_vswitch.vsw.id
        internet_max_bandwidth_out = 10
      }
      
      output "public_ip" {
          value = alicloud_instance.instance.public_ip
      }

      说明

      • 在上述示例中，指定了internet_max_bandwidth_out= 10，因此会自动为实例分配一个公网IP，输出到 output 中。

      • 详细的参数解释请参见 阿里云参数说明。

   2. 运行terraform apply开始创建。

   3. 运行terraform show查看已创建的ECS实例。

   4. 运行ssh root@<publicip>，并输入设定好的密码来访问ECS实例。